PLZ HELP - animation replication

[pink]

I'm trying to make a hologram - an item that creates an actor that every moment copies owner's animsequence, animframe etc. Basically it works except for
1) animframe - animsequence changes but animframe doesn't -
maybe it's possible to check player's animation and play it on item's own using playanim instead of copying animframes
2) movement not smooth

What is th way to solve the problems? Does anybody know? What kind of replication is best for such actors?
mb there's something similar done for ut?

[Age]

Something like:

Code: Select all

function Tick(float deltatime)
{
        AnimFor(Pawn(Owner));
}
function AnimFor(actor Other)
{
      if(Other!=None)
      {
            AnimSequence = Other.AnimSequence;
            AnimFrame = Other.AnimFrame;
            AnimRate = Other.AnimRate;
            TweenRate = Other.TweenRate;
            AnimMinRate = Other.AnimMinRate;
            AnimLast = Other.AnimLast;
            bAnimLoop = Other.bAnimLoop;
            SimAnim.X = 10000 * Other.AnimFrame;
            SimAnim.Y = 5000 * Other.AnimRate;
            SimAnim.Z = 1000 * Other.TweenRate;
            SimAnim.W = 10000 * Other.AnimLast;
            bAnimFinished = Other.bAnimFinished;
      }
}

or

Code: Select all

function Tick(float deltatime)
{
        AnimFor(yourhologram);
}
function AnimFor(actor Other)
{
      if(Other!=None)
      {
            Other.AnimSequence = Pawn(Owner).AnimSequence;
            Other.AnimFrame = Pawn(Owner).AnimFrame;
            Other.AnimRate = Pawn(Owner).AnimRate;
            Other.TweenRate = Pawn(Owner).TweenRate;
            Other.AnimMinRate = Pawn(Owner).AnimMinRate;
            Other.AnimLast = Pawn(Owner).AnimLast;
            Other.bAnimLoop = Pawn(Owner).bAnimLoop;
            Other.SimAnim.X = 10000 * Pawn(Owner).AnimFrame;
            Other.SimAnim.Y = 5000 * Pawn(Owner).AnimRate;
            Other.SimAnim.Z = 1000 * Pawn(Owner).TweenRate;
            Other.SimAnim.W = 10000 * Pawn(Owner).AnimLast;
            Other.bAnimFinished = Pawn(Owner).bAnimFinished;
      }
}

[Bane]

AnimFrame is not replicated, which is likely your problem (I assume this works fine offline). Setting it every tick clientside (like in Age's code, but you'll need to make tick and AnimFor simulated) should fix it, and you honestly should be trying to set everything you can clientside and replicate as little as possible. I don't think there's anything for this problem that you'd need to replicate. For the movement, try PHYS_Trailer. It natively adjusts movement and rotation. I believe you want the location to be at an offset from the owner. There's a variable for that and another one to make rotation the same. Try going here for information on PHYS_Trailer: http://chimeric.beyondunreal.com/tutorials/tut27.php

[Age]

Code: Select all

replication
{
unreliable if( Role==ROLE_Authority )
AnimFor;
}
simulated function AnimFor(actor a)
{
...
}

[pink]

Thank you guys, that really was helpful.
I solved the problem using simulated function AnimFor, but phys_trailer is quite a discovery.
Thank you again!