Trying to prevent item redundancy upon level load, how would that be fixed?

[Martin Vole]

Code: Select all

var() class PowerSuitType;

var inventory RedundantSuit;

function PreBeginPlay()
{
      local inventory PowSuit;
      
      RedundantSuit = Findinventorytype(PowerSuitType);
      //ClientMessage("Do I have a:"@RedundantSuit@"?");
      If (PowerSuitType != None && !bInventoryLoaded && RedundantSuit == None)
      {
            PowSuit=Spawn(PowerSuitType,Self,,self.location);
            PowSuit.GiveTo(Self);
            bInventoryLoaded = True;
      }
      Super.PreBeginPlay();
}

The idea here is that, upon first load, the PowerSuit of the type specified is given to the player, but afterwards, no new ones are added as each level is loaded to prevent redundant suits being given. What ACTUALLY happens is, that after each level load, another suit is given and any redundancy check is ignored.

There must be something I'm missing here.

Edit: Holy crap, I've placed in dozens of prevention checks and it still duplicates like rabbits in heat after each level load. What the hell is this? Seriously, is there something specific to PreBeginPlay or something that makes it largely unsuitable?

Edit 2: Prettied up ordering.

Edit 3: This is relevant only to single player modes, mind.

[[]KAOS[]Casey]

Try using PostBeginPlay and not PreBeginPlay, your inventory chain is probably not complete or even initialized yet during PreBeginPlay

[Martin Vole]

Try using PostBeginPlay and not PreBeginPlay, your inventory chain is probably not complete or even initialized yet during PreBeginPlay

Code: Select all

var() class PowerSuitType;

var inventory RedundantSuit;

event PostBeginPlay()
{
      local inventory PowSuit;
      
      RedundantSuit = Findinventorytype(PowerSuitType);
      //ClientMessage("Do I have a:"@RedundantSuit@"?");
      If (PowerSuitType != None && !bInventoryLoaded && RedundantSuit == None)
      {
            PowSuit=Spawn(PowerSuitType,Self,,self.location);
            PowSuit.GiveTo(Self);
            bInventoryLoaded = True;
      }
      Super.PostBeginPlay();
}

Still seems to be duplicating itself after each level load. Also, doesn't seem to give the item at all in deathmatch modes.

[[]KAOS[]Casey]

I assume the class that's executing this code is some kind of playerpawn?

edit: if that's the case, try using:

Code: Select all

event TravelPostAccept()
{
      local inventory PowSuit;

      Super.TravelPostAccept();

      RedundantSuit = Findinventorytype(PowerSuitType);
      //ClientMessage("Do I have a:"@RedundantSuit@"?");
      If (PowerSuitType != None && !bInventoryLoaded && RedundantSuit == None)
      {
            PowSuit=Spawn(PowerSuitType,Self,,self.location);
            PowSuit.GiveTo(Self);
            bInventoryLoaded = True;
      }
} 

[Martin Vole]

Oh wow, that actually worked! Fixed both the issues! Many thanks! I didn't even know about that event call, that will be nifty to have to apply to a number of other mods I'm messing with.

[[]KAOS[]Casey]

For reference "TravelPostAccept" is called after your inventory chain is guaranteed to be initialized. This is also called in the inventory classes themselves, you can see an example in Amplifier (check 227 versions, pre 227 has a bug)