Does anyone know how or if "Extent" works in Trace?

[スマイル・ドラゴン]

Code: Select all

native(277) final function Actor Trace
(
      out vector      HitLocation,
      out vector      HitNormal,
      vector          TraceEnd,
      optional vector TraceStart,
      optional bool   bTraceActors,
      optional vector Extent
);

I would like to beable to perform a "cylindrical" style trace or atleast have some sort of bounds checking along the X and Y axis rather than just test a straight line upward.

Is this what "Extent" is for? Or is this variable broken and I need to perform multiple tests?

I'm trying to refine this code so instead of just producing a line it produces some sort of box like test instead:

Code: Select all

if( bReducedCrouchHeight ) //Prevent getting up if somethings in the damn way.
{
      StartTrace = Location;
      EndTrace = Location;
      EndTrace.Z += 64.0;
      Trace( HitLocation, HitNormal, EndTrace, StartTrace, false);
}

[gopostal]

There are probably better ways of doing it but what I always did was create an item that had the dimensions of what box/area/whatever you need to check is empty. Draw your trace and test spawn the item at the trace point. If it spawns then you have room and you can immediately destroy it and do whatever you need to do. If the spawn fails then something is encroaching.

For this usage I'd create a cylinder with whatever height you want to check and try to spawn it over the head of the player. That would tell you if you have room.

I'm curious though how the better coders here will tell you how to do this. I never felt like my way was very good.

[スマイル・ドラゴン]

Testing with a "if( Move(NewLoc) )" statement somewhat works but it's still not entirely perfect.

And I'd still would love to know about this "Extent" optional variable in Trace.

[Bleeder91[NL]]

Extend does give some width to the Trace. An example is in the 227 RealCrouch code, where it checks for anything above the player to collide with, when trying to uncrouch:

Code: Select all

simulated final function bool TryToDuck( bool bCrouching )
{
      local vector Dummy,Offset,Start;

      if( !Level.bSupportsRealCrouching || bIsReducedCrouch==bCrouching )
            return true;
      if( bCrouching )
      {
            SetCrouch(true);
            return true;
      }
      // Make sure theres space to get up.
      Start = Location;
      Start.Z = Location.Z+CollisionHeight-0.01f;
      Offset.Z = ((CollisionHeight/CrouchHeightPct)-CollisionHeight);
      if( Trace(Dummy,Dummy,Start+Offset,Start,true,vect(1.f,1.f,0.f)*CollisionRadius)!=None )
            return false; // Wasnt enough space to uncrouch.
      SetCrouch(false);
      return true;
}

Though I'm not sure if it's actually a cylindrical or box radius.

[スマイル・ドラゴン]

Also another question. TraceStart is a optional variable. Does this mean the TraceStart becomes the calling Actor's Location if it's not defined in the function call?

[Bleeder91[NL]]

TraceStart defaults to Location, yes.

[スマイル・ドラゴン]

Extent seems to work like it should in this instance, I finally got my crouching check to properly examine the surroundings.

Though another question arises, how does Extent work if you wanted to make a "fat" trace? Like, a hitscan weapon with a wide collision radius on the hitscan itself.

[[]KAOS[]Casey]

Set extent to vect(WIDE_NUMBER,0.001,0.001). From what I understand "extent" is just a box/cube with the dimensions X/Y/Z when checking for trace hits. A large X and a small Y/Z should accomplish what you want.