Code:

function Tick(float DeltaTime)
{      
        DeltaTime = FMin(DeltaTime, 0.014);
        SimTick(DeltaTime);
}

simulated function SimTick(float DeltaTime)
{ 

1.) Calling a simulated function from a non-simulated function will never work on the client. Clients need a simulated function event as an entry point for simulation.
2.) Why not just make Tick itself simulated?
3.) Why are you doing FMIN?
4.) You are not calling super.tick. This causes strange behavior online sometimes.

To put it simple, this is all you need:
Code:

class VelocityTest extends Inventory;

simulated function Tick(float DeltaTime)
{
	Super.Tick(deltatime);
	if( Owner!=None && (Level.NetMode!=NM_Client || (PlayerPawn(Owner)!=None && Viewport(PlayerPawn(Owner).Player)!=None)) )
		MovePlayer(DeltaTime);
}
simulated function MovePlayer(float DeltaTime)
{
	if( Owner.Physics != Phys_Flying )
		Owner.SetPhysics(Phys_Flying);
	Owner.Velocity = Owner.Velocity + vector(Pawn(Owner).ViewRotation)*1000; // Move forward.
}
function BecomeItem()
{
	bHidden       = true;
	bCarriedItem  = true;
	NetPriority   = 2;
	SetCollision( false, false, false );
	SetPhysics(PHYS_None);
	SetTimer(0.0,False);
	AmbientGlow = 0;
}

defaultproperties
{
	RemoteRole=ROLE_SimulatedProxy
}