That's easy. Make your projectiles with collision (look at Shock Rifle), and make a check that if one projectile is damaged by the damage type of the laser itself (or anything else, if you like to create explosions from non-laser collides), and then when a hit is detected, create a huge explosion.

It's these default properties that make ShockProj collide:
Code:

     CollisionRadius=12.000000
     CollisionHeight=12.000000
     bProjTarget=True
 

Also lemme clarify that this gun shoots two straight beams , primary shoots a long blue beam with less damage.....the Alt shoots a shorter red Instant kill beam.....

-{oToD}Dentures

I've done these things. Like GreatEmerald said, you have to check it in ProcessTraceHit.

Code:

function ProcessTraceHit(Actor Other, Vector HitLocation, Vector HitNormal, Vector X, Vector Y, Vector Z)
{
	if ( LaserBeam(Other)!=None )
	{
		Other.Instigator = Pawn(Owner);
		LaserBeam(Other).SuperExplosion();
	}
	else if ( Other!=None && Other!=Self )
	{
		Other.TakeDamage(10, Pawn(Owner), HitLocation, 30000.0*X, 'laz0red');
		Spawn(class'LaserHitWallEffect',,, HitLocation+HitNormal*9, Rotator(HitNormal));
	}
} 

Of course, that's what it'd be if your beam's class is LaserBeam, the laser's wall hit effect is LaserHitWallEffect, desired damage on direct hit is 10, momentum 30000 and damage type "laz0red".

Here is my code.... Which has NOT be altered...well, what alterations I did, i erased so you guys could see the original. I tried the code examples you guys gave me, no luck, maybe itd make more sence to you guys if ya see it full blown. The first is from Class'LasergunV5', and the second is Class'ReBolt', which of course is the projectile...there is another class which is called RedBeam which extends RedBolt...lemme know if you guys need to look at it.
Appreciate this..
=========================

////////////////////////////////////////////////////////////////////////////////

///{oToD}LaserGun: Created by {oToD}Dentures. Special Thanks to -=CON=-Strych9.
////////////////////////////////////////////////////////////////////////////////

class LaserGunV5 extends TournamentWeapon;

var float Angle, Count;
var BlueBolt BLaser;
var() sound DownSound;
var RedBolt RLaser;

simulated event RenderOverlays( canvas Canvas )
{
    Texture'Ammoled'.NotifyActor = Self;
    Super.RenderOverlays(Canvas);
    Texture'Ammoled'.NotifyActor = None;
}

simulated function Destroyed()
{
    if ( BLaser != None )
       BLaser.Destroy();
    if ( RLaser != None )
       RLaser.Destroy();
    Super.Destroyed();
}

simulated function AnimEnd()
{
    if ( (Level.NetMode == NM_Client) && (Mesh != PickupViewMesh) )
    {
       if ( AnimSequence == 'SpinDown' )
           AnimSequence = 'Idle';
       PlayIdleAnim();
    }
}

function setHand(float Hand)
{
     Super.SetHand(Hand);
       if( Hand == 1 );
       mesh = mesh(DynamicLoadObject("Botpack.PulseGunR", class'Mesh'));
}

function float SuggestAttackStyle()
{
    local float EnemyDist;

    EnemyDist = VSize(Pawn(Owner).Enemy.Location - Owner.Location);
    if ( EnemyDist < 800 )
       return 0.4;
    else
       return 0;
}

function float RateSelf( out int bUseMode )
{
    local Pawn P;

    if ( AmmoType.AmmoAmount <=0 )
       return -2;

    P = Pawn(Owner);
    if ( (P.Enemy == None) || (Owner.IsA('Bot') && Bot(Owner).bQuickFire) )
    {
       bUseMode = 0;
       return AIRating;
    }

    if ( P.Enemy.IsA('StationaryPawn') )
    {
       bUseMode = 0;
       return (AIRating + 0.4);
    }
    else
       bUseMode = int( 700 > VSize(P.Enemy.Location - Owner.Location) );

    AIRating *= FMin(Pawn(Owner).DamageScaling, 1.5);
    return AIRating;
}

simulated function PlayFiring()
{

    AmbientSound = FireSound;
    if ( (AnimSequence == 'BoltLoop') || (AnimSequence == 'BoltStart') )
       PlayAnim( 'boltloop');
    else
       PlayAnim( 'boltstart' );
}

simulated function PlayAltFiring()
{

    AmbientSound = AltFireSound;
    if ( (AnimSequence == 'BoltLoop') || (AnimSequence == 'BoltStart') )
       PlayAnim( 'boltloop');
    else
       PlayAnim( 'boltstart' );
}
function Fire( float Value )
{
    if ( AmmoType == None )
    {
       GiveAmmo(Pawn(Owner));
    }
    if (AmmoType.UseAmmo(1))
    {
       GotoState('Firing');
       bCanClientFire = true;
       bPointing=True;
       Pawn(Owner).PlayRecoil(FiringSpeed);
       ClientFire(value);
       if ( BLaser == None )
       {
           BLaser = BlueBolt(ProjectileFire(ProjectileClass, AltProjectileSpeed, bAltWarnTarget));
           if ( FireOffset.Y == 0 )
               BLaser.bCenter = true;
           else if ( Mesh == mesh'PulseGunR' )
               BLaser.bRight = false;
       }
    }
}
function AltFire( float Value )
{
    if ( AmmoType == None )
    {
       GiveAmmo(Pawn(Owner));
    }
    if (AmmoType.UseAmmo(1))
    {
       GotoState('AltFiring');
       bCanClientFire = true;
       bPointing=True;
       Pawn(Owner).PlayRecoil(FiringSpeed);
       ClientAltFire(value);
       if ( RLaser == None )
       {
           RLaser = RedBolt(ProjectileFire(AltProjectileClass, AltProjectileSpeed, bAltWarnTarget));
           if ( FireOffset.Y == 0 )
               RLaser.bCenter = true;
           else if ( Mesh == mesh'PulseGunR' )
               RLaser.bRight = false;
       }
    }
}

state ClientFiring
{
    simulated function Tick( float DeltaTime )
    {
       if ( (Pawn(Owner) != None) && (Pawn(Owner).bFire != 0) )
           AmbientSound = FireSound;
       else
           AmbientSound = None;
    }

    simulated function AnimEnd()
    {
       if ( (AmmoType != None) && (AmmoType.AmmoAmount <= 0) )
       {
           GotoState('');
       }
       else if ( !bCanClientFire )
           GotoState('');
       else if ( Pawn(Owner) == None )
       {
           GotoState('');
       }
       else if ( Pawn(Owner).bFire != 0 )
           Global.ClientFire(0);
       else if ( Pawn(Owner).bAltFire != 0 )
           Global.ClientAltFire(0);
       else
       {
           GotoState('');
       }
    }
}
state ClientAltFiring
{
    simulated function AnimEnd()
    {
       if ( AmmoType.AmmoAmount <= 0 )
       {
           PlayIdleAnim();
           GotoState('');
       }
       else if ( !bCanClientFire )
           GotoState('');
       else if ( Pawn(Owner) == None )
       {
           PlayIdleAnim();
           GotoState('');
       }
       else if ( Pawn(Owner).bAltFire != 0 )
           LoopAnim('BoltLoop');
       else if ( Pawn(Owner).bFire != 0 )
           Global.ClientFire(0);
       else
       {
           PlayIdleAnim();
           GotoState('');
       }
    }
}
state Firing
{
    ignores AnimEnd;

    function Tick(float DeltaTime)
    {
       local Pawn P;

       P = Pawn(Owner);
       if ( P == None )
       {
           GotoState('Pickup');
           return;
       }
       if ( (P.bFire == 0) || (P.IsA('Bot')
       && ((P.Enemy == None) || (Level.TimeSeconds - Bot(P).LastSeenTime > 5))) )
       {
           P.bFire = 0;
           Finish();
           return;
       }

       Count += Deltatime;
       if ( Count > 0.24 )
       {
           if ( Owner.IsA('PlayerPawn') )
               PlayerPawn(Owner).ClientInstantFlash( InstFlash,InstFog);
           if ( Affector != None )
               Affector.FireEffect();
           Count -= 0.24;
           if ( !AmmoType.UseAmmo(1) )
               Finish();
       }
    }
    function EndState()
    {
       AmbientGlow = 0;
       AmbientSound = None;
       if ( BLaser != None )
       {
           BLaser.Destroy();
           BLaser = None;
       }
       Super.EndState();
    }

Begin:
    AmbientGlow = 200;
    FinishAnim();
    LoopAnim( 'boltloop');
}
state AltFiring
{
    ignores AnimEnd;

    function Tick(float DeltaTime)
    {
       local Pawn P;
       local Redbeam i;

       P = Pawn(Owner);
       if ( P == None )
       {
           GotoState('Pickup');
           return;
       }
       if ( (P.bAltFire == 0) || (P.IsA('Bot')
                   && ((P.Enemy == None) || (Level.TimeSeconds - Bot(P).LastSeenTime > 5))) )
       {
           P.bAltFire = 0;
           Finish();
           return;
       }

       Count += Deltatime;
       if ( Count > 0.24 )
       {
           if ( Owner.IsA('PlayerPawn') )
               PlayerPawn(Owner).ClientInstantFlash( InstFlash,InstFog);
           if ( Affector != None )
               Affector.FireEffect();
           Count -= 0.24;
           if ( !AmmoType.UseAmmo(1) )
               Finish();
       }
    }
    function EndState()
    {
       AmbientGlow = 0;
       AmbientSound = None;
       if ( RLaser != None )
       {
           RLaser.Destroy();
           RLaser = None;
       }
       Super.EndState();
    }

Begin:
    AmbientGlow = 200;
    FinishAnim();
    LoopAnim( 'boltloop');
}

state Idle
{
Begin:
    bPointing=False;
    if ( (AmmoType != None) && (AmmoType.AmmoAmount<=0) )
       Pawn(Owner).SwitchToBestWeapon();
    if ( Pawn(Owner).bFire!=0 ) Fire(5.0);
    if ( Pawn(Owner).bAltFire!=0 ) AltFire(0.0);

    Disable('AnimEnd');
    PlayIdleAnim();
}

simulated function PlayIdleAnim()
{
    if ( Mesh == PickupViewMesh )
       return;

    if ( (AnimSequence == 'BoltLoop') || (AnimSequence == 'BoltStart') )
       PlayAnim('BoltEnd');
    else if ( AnimSequence != 'SpinDown' )
       TweenAnim('Idle', 0.1);
}

simulated function TweenDown()
{
    if ( IsAnimating() && (AnimSequence != '') && (GetAnimGroup(AnimSequence) == 'Select') )
       TweenAnim( AnimSequence, AnimFrame * 0.4 );
    else
       TweenAnim('Down', 0.26);
}
defaultproperties
{
     AmmoName=Class'LaserAmmo'
     PickupAmmoCount=500
     bRapidFire=True
     FireOffset=(X=15.000000,Y=-15.000000,Z=2.000000)
     ProjectileClass=Class'BlueBeam'
     AltProjectileClass=Class'RedBeam'
     shakemag=0.000000
     shakevert=0.000000
     AIRating=0.700000
     RefireRate=0.950000
     AltRefireRate=0.990000
     FireSound=Sound'PrimFire'
     AltFireSound=Sound'LaserFire'
     MessageNoAmmo=" has no laser."
     DeathMessage="%k turned %o into crispy bacon with the {oToD}LaserGun."
     AutoSwitchPriority=5
     InventoryGroup=5
     PickupMessage="You found another Laser Gun"
     ItemName="Pulse Gun"
     PlayerViewOffset=(X=1.500000,Z=-2.000000)
     PlayerViewMesh=LodMesh'PulseGunR'
     PickupViewMesh=LodMesh'PulsePickup'
     ThirdPersonMesh=LodMesh'PulseGun3rd'
     ThirdPersonScale=0.400000
     StatusIcon=Texture'UsePulse'
     PickupSound=Sound'LaserPickup'
     SelectSound=Sound'LaserPickup'
     Icon=Texture'UsePulse'
     Mesh=LodMesh'PulsePickup'
     bNoSmooth=False
     SoundRadius=64
     MultiSkins(1)=Texture'LaserGun3rd'
     MultiSkins(2)=Texture'LaserGun_01'
     SoundVolume=255
     CollisionRadius=32.0
     WeaponDescription="LaserGun"
     NameColor=(R=255,G=0,B=0)
}
==========================
////////////////////////////////////////////////////////////////////////////////

///{oToD}LaserGun: Created by {oToD}Dentures. Special Thanks to -=CON=-Strych9.
////////////////////////////////////////////////////////////////////////////////

class RedBolt extends projectile;

var() texture SpriteAnim[5];
var int SpriteFrame;
var RedBolt RedBeam;
var LaserCap WallEffect;
var int Position;
var vector FireOffset;
var float BeamSize;
var bool bRight, bCenter;
var float AccumulatedDamage, LastHitTime;
var Actor DamagedActor;

replication
{
     unreliable if( Role==ROLE_Authority )
           bRight, bCenter;
}

simulated function Destroyed()
{
     Super.Destroyed();
     if ( RedBeam != None )
           RedBeam.Destroy();
     if ( WallEffect != None )
           WallEffect.Destroy();
}

simulated function CheckBeam(vector X, float DeltaTime)
{
     local actor HitActor, Projectile Touch;
     local vector HitLocation, HitNormal;
     HitActor = Trace(HitLocation, HitNormal, Location + BeamSize * X, Location, true);
     if ( (HitActor != None)      && (HitActor != Instigator)
           && (HitActor.bProjTarget || (HitActor == Level) || (HitActor.bBlockActors && HitActor.bBlockPlayers))
           && ((Pawn(HitActor) == None) || Pawn(HitActor).AdjustHitLocation(HitLocation, Velocity)) )
     {
           if ( Level.Netmode != NM_Client )
           {
                 if ( DamagedActor == None )
                 {
                       AccumulatedDamage = FMin(0.5 * (Level.TimeSeconds - LastHitTime), 0.1);
                       HitActor.TakeDamage(damage * AccumulatedDamage, instigator,HitLocation,
                             (MomentumTransfer * X * AccumulatedDamage), MyDamageType);
                       AccumulatedDamage = 15;
                 }
                 else if ( DamagedActor != HitActor )
                 {
                       DamagedActor.TakeDamage(damage * AccumulatedDamage, instigator,HitLocation,
                             (MomentumTransfer * X * AccumulatedDamage), MyDamageType);
                       AccumulatedDamage = 15;
                 }
                 LastHitTime = Level.TimeSeconds;
                 DamagedActor = HitActor;
                 AccumulatedDamage += DeltaTime;
                 if ( AccumulatedDamage > 15.0 )
                 {
                       if ( DamagedActor.IsA('Carcass') && (FRand() < 0.09) )
                             AccumulatedDamage = 35/damage;
                       DamagedActor.TakeDamage(damage * AccumulatedDamage, instigator,HitLocation,
                             (MomentumTransfer * X * AccumulatedDamage), MyDamageType);
                       AccumulatedDamage = 15;
                 }
           }
           if ( HitActor.bIsPawn && Pawn(HitActor).bIsPlayer )
           {
                 if ( WallEffect != None )
                       WallEffect.Destroy();
           }
           else if ( (WallEffect == None) || WallEffect.bDeleteMe )
                 WallEffect = Spawn(class'LaserHit',,, HitLocation - 5 * X);
           else if ( !WallEffect.IsA('LaserHit') )
           {
                 WallEffect.Destroy();
                 WallEffect = Spawn(class'LaserHit',,, HitLocation - 5 * X);
           }
           else
                 WallEffect.SetLocation(HitLocation - 5 * X);

           if ( (WallEffect != None) && (Level.NetMode != NM_DedicatedServer) )
                 Spawn(ExplosionDecal,,,HitLocation,rotator(HitNormal));

           if ( RedBeam != None )
           {
                 AccumulatedDamage += RedBeam.AccumulatedDamage;
                 RedBeam.Destroy();
                 RedBeam = None;
           }

           return;
     }
     else if ( (Level.Netmode != NM_Client) && (DamagedActor != None) )
     {
           DamagedActor.TakeDamage(damage * AccumulatedDamage, instigator, DamagedActor.Location - X * 1.2 * DamagedActor.CollisionRadius,
                 (MomentumTransfer * X * AccumulatedDamage), MyDamageType);
           AccumulatedDamage = 15;
           DamagedActor = None;
     }


     if ( Position >= 9 )
     {
           if ( (WallEffect == None) || WallEffect.bDeleteMe )
                 WallEffect = Spawn(class'LaserCap',,, Location + (BeamSize - 0) * X);
           else if ( WallEffect.IsA('LaserCap') )
           {
                 WallEffect.Destroy();
                 WallEffect = Spawn(class'LaserCap',,, Location + (BeamSize - 0) * X);
           }
           else
                 WallEffect.SetLocation(Location + (BeamSize - 0) * X);
     }
     else
     {
           if ( WallEffect != None )
           {
                 WallEffect.Destroy();
                 WallEffect = None;
           }
           if ( RedBeam == None )
           {
                 RedBeam = Spawn(class'RedBolt',,, Location + BeamSize * X);
                 RedBeam.Position = Position + 1;
           }
           else
                 RedBeam.UpdateBeam(self, X, DeltaTime);
     }
}

simulated function UpdateBeam(RedBolt ParentBolt, vector Dir, float DeltaTime)
{
     local actor HitActor;
     local vector HitLocation, HitNormal;

     SpriteFrame = ParentBolt.SpriteFrame;
     Skin = SpriteAnim[SpriteFrame];
     SetLocation(ParentBolt.Location + BeamSize * Dir);
     SetRotation(ParentBolt.Rotation);
     CheckBeam(Dir, DeltaTime);
}
defaultproperties
{
    ExplosionDecal=class'LaserScorch'
    SpriteAnim(0)=Texture'beam0'
    SpriteAnim(1)=Texture'beam1'
    SpriteAnim(2)=Texture'beam2'
    SpriteAnim(3)=Texture'beam3'
    SpriteAnim(4)=Texture'beam4'
    Skin=Texture'beam0'
    Texture=Texture'beam0'
    BeamSize=50.00
    bUnlit=true
    FireOffset=(X=16.000000,Y=-14.000000,Z=-8.00000)
    DrawType=DT_Mesh
    Mesh=lbeam
    Style=STY_Translucent
    RemoteRole=ROLE_None
    MaxSpeed=+20000.000000
    SoundVolume=0
    CollisionRadius=+0.000000
    CollisionHeight=+0.000000
    bCollideActors=False
    bCollideWorld=False
    bNetTemporary=False
    bGameRelevant=true
    Physics=PHYS_None
    LifeSpan=+60.000000
    Damage=+90.000
    MomentumTransfer=8500
    bRight=True
    SoundVolume=255
}

Thanks For the reply I will try what you said.

It's collision RADIUS, which is a circle... I'd still stick with TraceFire which spawns colliding parts of the beam from start to end (like ASMD does, but in its case, it's not colliding) and check is that actor hit by another lazer beam, resulting in an enormous KABOOM!!

So when you define a collision radius and height, and add bProjTarget=true to the default properties, in theory it makes the projectile a hittable target? (i.e. Shock Rfile's Blue Ball?)...Could "RemoteRole", and "Physics" have anything to do with prohibiting the beam being a "solid" or hittable target?...Cuz in my mind, in order for something to be hittable it has to be solid...Just curious.

Yes Dentures.
RemoteRole only affects online games. If something doesn't work online, then usually that's the problem. Physics control how the projectile moves, that is, if it stays in place, flies straight, is affected by gravity, can climb walls etc.

Hmm... You don't need to. What's wrong with the TakeDamage method?